# The Medians of a Triangle Intersect at a Point

 Consider a general triangle of vertices A,B and C. Let the sides AB,BC and CA be represented by the vectors, a,b and c resp. More over let the median that starts at the vertice A and ends at the middle point along BC be denoted by m1 and simmilarly let m2 be the median from B to the middle point on CA and le m3 be the median from C to the middle point on AB. Finally let P be the point of intersection of m2 with m3. We have,

> Triangle := a+b+c = 0;

`                           Triangle := a + b + c = 0`
 With our notation the first hint that: CN = (1/2)AB - AC can be extracted from the picture as,

> Median3 := m3-a/2 = c;

`                           Median3 := m3 - 1/2 a = c`
 and similarly for the other part that, BM = (1/2)AC - AB

> Median2 := m2-c/2 = b;

`                           Median2 := m2 - 1/2 c = b`
 We also have an analogous relationship for the first Median,

> Median1 := m1 - b/2 = a;

`                           Median1 := m1 - 1/2 b = a`
 Hint2 says that the only scalars r and s that satisfy,

> Hint2 := s*m2-r*m3 = b;

`                           Hint2 := s m2 - r m3 = b`
 replacing m2 and m3 with the solutions of Median2 and Median3 we obtain,

> Eq := s*solve(Median2,m2) - r*solve(Median3,m3) = b;

`                    Eq := s (1/2 c + b) - r (1/2 a + c) = b`
> Eq1 := subs(c=-(a+b),Eq);
`               Eq1 := s (- 1/2 a + 1/2 b) - r (- 1/2 a - b) = b`
> Eq2 := collect(lhs(Eq1)-b,[a,b]) = 0;
`              Eq2 := (- 1/2 s + 1/2 r) a + (-1 + 1/2 s + r) b = 0`
 Now, since a and b are not on a line (i.e. they are linearly independent) then the only way in which Eq2 can be true is that the coefficients that multiply a and b are both zero. Hence, we obtain that

> E1 := coeff(lhs(Eq2),a) = 0; E2 := coeff(lhs(Eq2),b) = 0;

```                           E1 := - 1/2 s + 1/2 r = 0

E2 := -1 + 1/2 s + r = 0```
 from where we obtain the solution:

> Sol := solve({E1,E2},{r,s});

`                           Sol := {s = 2/3, r = 2/3}`
 From the fact that s = r = 2/3 and the fact that the same reasoning applied to any pair of Medians (not just m2 and m3) would give the same answer we conclude that the three medians must meet at a single point.

### Coordinates of P

 Now suppose that,

> A := vector([x1,y1]): B := vector([x2,y2]): C := vector([x3,y3]):
 then it follows that,

> a := evalm(B-A); b := evalm(C-B); c := evalm(A-C);

```                            a := [x2 - x1, y2 - y1]

b := [x3 - x2, y3 - y2]

c := [x1 - x3, y1 - y3]```
 In this coordinate system we have, P = A + (2/3) m1 and replaing m1 by a+b/2 we obtain that the coordinates of the point P are then given by,

> P := evalm(A + (2/3)*(a+(1/2)*b));

`           P := [1/3 x1 + 1/3 x2 + 1/3 x3, 1/3 y1 + 1/3 y2 + 1/3 y3]`

Link to the commands in this file
Carlos Rodriguez <carlos@math.albany.edu>