# Review Exercises

### Problem 1

Given,

> y := 3*x^3-2*x^2+5;

```                                      3      2
y := 3 x  - 2 x  + 5```

a) Find the length from x=0 to x=1.
b) Find the curvature at x=1/2.
c) Give a parametrization as a space curve.
d) Compute the unit tangent vector at x=1/2.

#### Sol 1

a) the length is:

> lth := Int(sqrt(1+ (diff(y,x))^2),x=0..1);

```                           1
/
|           4       3       2 1/2
lth :=  |  (1 + 81 x  - 72 x  + 16 x )    dx
|
/
0```
> sol_a := evalf(lth);
`                              sol_a := 1.796448727`
 b) For the curvature we use the formula when y=f(x).

> k = diff(diff(f(x),x),x)/ (1+diff(f(x),x)^2)^(3/2);

```                                        2
d
----- f(x)
2
dx
k = ---------------------
/    /  d      \2\3/2
|1 + |---- f(x)| |
\    \ dx      / /```
> y1 := diff(y,x); y2 := diff(y1,x); k := y2/(1+y1^2)^(3/2);
```                                         2
y1 := 9 x  - 4 x

y2 := 18 x - 4

18 x - 4
k := ----------------------
2       2 3/2
(1 + (9 x  - 4 x) )```
 So at x=1/2 we get,

> sol_b := evalf(subs(x=1/2,k));

`                              sol_b := 4.565376471`
 c) The parametrization as a space curve can be obtained by letting t=x.

> r := t -> t*i+(3*t^3-2*t^2+5)*j: 'r(t)' = r(t);

```                                         3      2
r(t) = t i + (3 t  - 2 t  + 5) j```
 d) The derivative of r(t) gives a vector tangent to the curve so,

> sol_d := subs(t=1/2, [1, 9*t^2-4*t]/sqrt(1+(9*t^2+4*t)^2));

```                                                 1/2   1/2
sol_d := 1/305 [1, 1/4] 305    16```
> sol_d := evalf(evalm(sol_d));
`                     sol_d := [ .2290393338, .05725983345 ]`

### Problem 2

The velocity of a particle moving in space is,

> k := 'k': v := t -> ln(1+t)*i - (t^2+1)*j - t*cos(t)*k: 'v(t)' = v(t);

```                                         2
v(t) = ln(1 + t) i - (t  + 1) j - t cos(t) k```

if at t=0 the particle is at the origin, find the position of the particle at t=1.

#### Sol 2

Since the velocity vector is the derivative w.r. to time of the position vector R then,

> R := R0 + Int(v(s),s=0..t);

```                         t
/
|                  2
R := R0 +  |  ln(1 + s) i - (s  + 1) j - s cos(s) k ds
|
/
0```
 where R0 is, the position at t=0. We have

> R0 := 0: i:= 'i': j:='j':k:='k': R := subs(t=1,R);

```                      1
/
|                  2
R :=  |  ln(1 + s) i - (s  + 1) j - s cos(s) k ds
|
/
0```
> R := evalf(int(ln(1+s),s=0..1))*i-evalf(int(s^2+1,s=0..1))*j -
> evalf(int(s*cos(s),s=0..1))*k;
`                R := .386294361 i - 1.333333333 j - .381773291 k`

### Problem 3

Consider the function:

> x := 'x':y:='y':
> f := (x,y) -> (x^2+y^2-2*x-2*y)/(x^2+y^2-2*x+2*y+2): 'f(x,y)' = f(x,y);

```                                    2    2
x  + y  - 2 x - 2 y
f(x, y) = -----------------------
2    2
x  + y  - 2 x + 2 y + 2```
 Find the limit at (1,-1) it it exists. i.e.,

> #

```                                       2    2
x  + y  - 2 x - 2 y
Limit      -----------------------
(x,y) ->(1,-1)  2    2
x  + y  - 2 x + 2 y + 2```

#### Sol 3

If the function is continuous at (1,-1) all we need is to plug-in x=1 and y=-1 so let us first check if the function is at least defined at (1,-1)

> f(1,-1);

`Error, (in f) division by zero`
 So it is not continuous. The denominator is zero there. The limit may still exist however. Notice that the denominator can be factorized as,

> '(x-1)^2+(y+1)^2' = expand((x-1)^2+(y+1)^2);

```                        2          2    2    2
(x - 1)  + (y + 1)  = x  + y  - 2 x + 2 y + 2```
 Hence, since the denominator is the sum of two squares it is never negative. If we let r=(x,y) and r0=(1,-1) we have,

> #

```                  2    2
x  + y  - 2 x - 2 y
Limit   ----------------------- =
r -> r0  2    2
x  + y  - 2 x + 2 y + 2

/         2    2            \   /                 1         \
|Limit   x  + y  - 2 x - 2 y| * |Limit   -------------------|
\r -> r0                    /   |r -> r0        2          2|
\        (x - 1)  + (y + 1) /```

this is nothing but the limit of a product is the product of the limits which is true when all the limits exist. So the limit exists and it is 2*infinity which is just infinity.

### Problem 4

Given the function,

> x:='x':y:='y':f:=(x,y)->x*exp(-y)+3*y*cos(x): 'f(x,y)'= f(x,y);

`                       f(x, y) = x exp(- y) + 3 y cos(x)`

Find the partial derivative w.r.t. x at (-1,2) and w.r.t. y at (0,1/2).

#### Sol 4

We can use either unapply or subs. Let's use both,

> fx := unapply(diff(f(x,y),x),x,y)(-1,2);

`                            fx := exp(-2) + 6 sin(1)`
> fy := subs({x=0,y=1/2},diff(f(x,y),y));
`                                 fy := 3 cos(0)`
 or approximately

> fx := evalf(fx); fy := simplify(fy);

```                               fx := 5.184161192

fy := 3```

### Problem 5

Find a normal vector to the plane tangent to the graph of the function,

> z := sqrt(3*x+y^2);

```                                            2 1/2
z := (3 x + y )```

at the point (1,-1,2).

#### Sol 5

The tangent plane at (x0,y0,z0) has equation,

> A*(x-x0)+B*(y-y0)-('z'-z0) = 0;

`                      A (x - x0) + B (y - y0) - z + z0 = 0`
 where, A and B are the partials w.r.t. x and y resp. at the given point. i.e.

> A := subs({x=1,y=-1},diff(z,x)); B := subs({x=1,y=-1},diff(z,y)); C:=-1;

```                                           1/2
A := 3/8 4

1/2
B := - 1/4 4

C := -1```
 so a normal to the plane will be,

> N := [simplify(A),simplify(B),-1];

`                              N := [3/4, -1/2, -1]`

### Problem 6

Use differentials to approximate,

> #

```                                     2        2  1/2
(9 (1.95)    + 8.1   )```

#### Sol 6

We first notice that the exact value is f(1.95,8.1) where,

> f := (x,y) -> sqrt(9*x^2+y^2): 'f(x,y)' = f(x,y);

```                                          2    2 1/2
f(x, y) = (9 x  + y )```
 So the approxiamation is,

> 'f(1.95,8.1)' = 'f(2,8)'+ 'fx'*dx + 'fy'*dy + bit_more;

`               f(1.95, 8.1) = f(2, 8) + fx dx + fy dy + bit_more`
 where,

> fx :=simplify(subs({x=2,y=8},diff(f(x,y),x)));

`                                   fx := 9/5`
> fy :=simplify(subs({x=2,y=8},diff(f(x,y),y)));
`                                   fy := 4/5`
> dx := 1.95-2; dy := 8.1-8;
```                                   dx := -.05

dy := .1```
 The approximation is then,

> apprx := f(2,8)+fx*dx+fy*dy;

`                              apprx := 9.990000000`
 The exact value is,

> exact := f(1.95,8.1);

`                              exact := 9.991621490`

### Problem 7

Let,

> f :='f': z := f(x,y);

`                                  z := f(x, y)`
 if x and y are given by,

> x := r^2+s^2; y := 2*r*s;

```                                        2    2
x := r  + s

y := 2 r s```
 Find,

> zs := Diff(z,s): Zrs := Diff(zs,r);

```                                   2
d  z
Zrs := -------
dr ds```

#### Sol 7

This is an application of the chain rule. But with maple we can use BRUTE force to get the answer directly:

> Zrs := simplify(diff(diff(z,s),r));

```                          2    2                           2    2          2
Zrs := 4 s D[1, 1](f)(r  + s , 2 r s) r + 4 D[1, 2](f)(r  + s , 2 r s) s

2    2          2                   2    2
+ 4 D[1, 2](f)(r  + s , 2 r s) r  + 4 r D[2, 2](f)(r  + s , 2 r s) s

2    2
+ 2 D[2](f)(r  + s , 2 r s)```
 where D[1,2](f)(x0,y0) is maple's notation for second order partial of x w.r.t. x and y evaluated at (x0,y0)... etc...

Link to the commands in this file
Carlos Rodriguez <carlos@math.albany.edu>